logo
logo
Fotos in Ordner sortieren lassen - Mac-TV.de
Zurück   Mac-TV.de > Rund um Apple und Technik > Macs, macOS und Zubehör
Registrieren Hilfe Suchen Heutige Beiträge Alle Foren als gelesen markieren

Antwort
 
Themen-Optionen Thema durchsuchen
  #1  
Alt 10.11.2021, 22:18
joerg0811 joerg0811 ist offline
Neuer Benutzer
 
Registriert seit: 21.08.2009
Beiträge: 10
Fotos in Ordner sortieren lassen

Hallo,

ich habe einen Ordner mit ca. 1000 Fotos.
Diese Fotos sollen automatisch in Ordner sortiert werden.
Die Dateinamen bestehen aus 10 Ziffern, wobei die ersten 5 Ziffern Ausschlag gebend für die Sortierung in die jeweiligen Ordner sind.
Beispiel:
2100100001.jpg soll in Ordner "Band21001" verschoben werden
2100200001.jpg soll in Ordner "Band21002" verschoben werden

Kann man so eine Aufgabe automatisieren, wenn ja, wie?



[IMG][/IMG]
Mit Zitat antworten
  #2  
Alt 11.11.2021, 14:35
Jörn Jörn ist offline
Administrator
 
Registriert seit: 05.01.2008
Beiträge: 9.438
Ja, das lässt sich automatisieren. Um welche Version von macOS handelt es sich? Big Sur oder Monterey?
Mit Zitat antworten
  #3  
Alt 11.11.2021, 15:07
joerg0811 joerg0811 ist offline
Neuer Benutzer
 
Registriert seit: 21.08.2009
Beiträge: 10
Ich habe schon auf Monterey aktualisiert.
Mit Zitat antworten
  #4  
Alt 11.11.2021, 15:27
Jörn Jörn ist offline
Administrator
 
Registriert seit: 05.01.2008
Beiträge: 9.438
Gut. Dann hätten wir also AppleScript, Automator und Shortcuts zur Verfügung.

Ich denke mir was aus und melde mich in Kürze wieder.
Mit Zitat antworten
  #5  
Alt 11.11.2021, 18:42
Jörn Jörn ist offline
Administrator
 
Registriert seit: 05.01.2008
Beiträge: 9.438
Aaaalso... anbei ist ein kleines AppleScript-Programm. Es schnappt sich die Dateien in einem Ordner und sortiert diese in Unterordner. Die Unterordner werden automatisch erzeugt.

Bevor Du die App startest:

Zuerst musst Du die Zugriffsrechte einräumen. Dies geschieht in den Systemeinstellungen, dort unter "Sicherheit & Datenschutz". Dort schaust Du in die Seitenleiste und wählst entweder "Festplattenvollzugriff" (dann hat die App Zugriff auf alle Dateien im System) oder "Dateien und Ordner" (dann kannst Du einzelne Ordner festlegen). Du fügst also die App bei einer der beiden Kategorien hinzu. Erst dann kannst Du sie starten.

Anleitung für die App:

1. Doppelklicke das App-Symbol

2. Ein Datei-Dialog öffnet sich. Gib den Ordner an, in dem sich alle zu sortierenden Fotos befinden (Quell-Ordner).

3. Ein weitere Datei-Dialog erscheint. Gib den Ordner an, der alle weiteren Unter-Ordner enthalten soll (Ziel-Ordner). Wenn der Ziel-Ordner noch nicht existiert, klicke unten im Dialog-Fenster auf den Button "Neuer Ordner", oder erzeuge einen neuen Ordner im Finder.

4. Anschließend rattert das Programm los. Es schaut sich die ersten fünf Buchstaben des Dateinamens an. Falls noch kein Ordner mit diesen Buchstaben existiert, wird er erzeugt. Dann werden alle Dateien in diese Ordner verschoben.

Vorsicht: Wenn eine Datei gleichen Namens im Ziel-Ordner bereits existieren sollte, wird die Datei überschrieben. Die App geht davon aus, dass alle Dateien einen einmaligen Namen haben.

5. Während des Vorgangs hörst Du eventuell Geräusche. Das sind die gleichen Geräusche, die der Finder beim Bewegen oder Kopieren von Dateien ausgibt. Es ist also völlig in Ordnung, wenn der Mac diese Geräusche macht.

6. Du kannst den Programmcode (AppleScript) ansehen, wenn Du die App startest und dann im Menü "Bearbeiten wählst: "Skript bearbeiten". Du kannst den Code natürlich auch ändern.

Viel Spaß und viel Erfolg!
Angehängte Dateien
Dateityp: zip Fotos sortieren.zip (58,5 KB, 30x aufgerufen)
Mit Zitat antworten
  #6  
Alt 11.11.2021, 21:33
joerg0811 joerg0811 ist offline
Neuer Benutzer
 
Registriert seit: 21.08.2009
Beiträge: 10
Hallo Jörn,
ich dachte das Programm erleichtert meine Arbeit einwenig und lässt mich Zeit sparen. Da habe ich mich aber geirrt.
Durch deine Hilfe habe ich einen Quantensprung gemacht.
Was mich sonst Stunden gekostet hätte, ist nun in 3 Minuten fertig.
Du bist einfach Spitze.

Allerdings kann ich das Skript nicht öffnen.
Mit Zitat antworten
  #7  
Alt 11.11.2021, 21:43
Jörn Jörn ist offline
Administrator
 
Registriert seit: 05.01.2008
Beiträge: 9.438
Und warum kannst Du das Skript nicht öffnen? Was hindert Dich daran? Erscheint eine Fehlermeldung?
Mit Zitat antworten
  #8  
Alt 12.11.2021, 06:47
joerg0811 joerg0811 ist offline
Neuer Benutzer
 
Registriert seit: 21.08.2009
Beiträge: 10
Das Fenster mit dem Original Fotos wird angezeigt, im Menü klicke ich auf Skript bearbeiten, und es passiert nichts. Auch keine Fehlermeldung.
Mit Zitat antworten
  #9  
Alt 12.11.2021, 10:36
Jörn Jörn ist offline
Administrator
 
Registriert seit: 05.01.2008
Beiträge: 9.438
Dann probiere folgendes, um an den Quellcode zu gelangen:

1. Öffne zunächst den AppleScript-Editor. Am einfachsten gibst Du bei Spotlight ein: "Skripteditor". (Der Editor befindet sich im Ordner "Programme -> Dienstprogramme".)

2. Es erscheint dann ein Datei-Dialog, um ein Skript zu öffnen. Du klickst aber auf "Abbrechen".

3. Nun ist der Skripteditor im Dock sichtbar.

4. Ziehe die "Fotos sortieren"-App auf das Symbol des Skripteditors im Dock. Dadurch wird die App als Quellcode im Editor geöffnet.

-----

Unten füge ich den Quellcode ein, vielleicht sucht jemand bei Google danach.

Code:
-- Nach Quellordner fragen
set Quellordner to choose folder with prompt "In welchem Ordner liegen die Original-Fotos?" default location (path to desktop folder as alias)
log "Pfad zum Quellordner ist: " & Quellordner

-- Nach Zielordner fragen
set Zielordner to choose folder with prompt "In welchem Ordner sollen die Unterordner entstehen?" default location (path to desktop folder as alias)
log "Pfad zum Zielordner ist: " & Zielordner


tell application "Finder"
	
	-- Liste mit allen Dateien im Quellordner erzeugen
	set Dateiliste_Quellordner to every file of folder (Quellordner as alias)
	
	-- Schleife durch alle diese Dateien
	repeat with Loop_AktuelleDatei in Dateiliste_Quellordner
		
		-- Erste fünf Buchstaben des Dateinamens isolieren und in die Variable "Sortierung" werfen
		set Sortierung to text 1 thru 5 of (get name of Loop_AktuelleDatei)
		log Sortierung
		
		-- Prüfen ob der erforderliche Unterordner bereits existiert
		set Unterordner_Pfad to (Zielordner as text) & "Band" & Sortierung & ":"
		set Unterordner_Name to "Band" & Sortierung
		log Unterordner_Pfad
		
		-- Ordner anlegen, falls er nicht existiert
		if not (exists folder Unterordner_Pfad) then
			make new folder at (Zielordner) with properties {name:Unterordner_Name}
		end if
		
		-- Datei in den Ordner bewegen
		move Loop_AktuelleDatei to Unterordner_Pfad with replacing
		
	end repeat
	
end tell
Mit Zitat antworten
Antwort


Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche

Forumregeln
Es ist Ihnen nicht erlaubt, neue Themen zu verfassen.
Es ist Ihnen nicht erlaubt, auf Beiträge zu antworten.
Es ist Ihnen nicht erlaubt, Anhänge anzufügen.
Es ist Ihnen nicht erlaubt, Ihre Beiträge zu bearbeiten.

vB Code ist An.
Smileys sind An.
[IMG] Code ist An.
HTML-Code ist Aus.
Gehe zu




Powered by vBulletin® Version 3.6.8 (Deutsch)
Copyright ©2000 - 2021, Jelsoft Enterprises Ltd.